Blog

Postado em em 28 de fevereiro de 2020

Calendário no Excel – Passo a Passo Simples e Detalhado

Aprenda a construir um Calendário no Excel de forma simples e detalhada, partindo do zero e com aplicações práticas!

Caso prefira esse conteúdo no formato de vídeo-aula, assista ao vídeo abaixo ou acesse o nosso canal do YouTube!

Para receber por e-mail o(s) arquivo(s) que utilizamos na aula, preencha:

Calendário no Excel – Passo a Passo Simples e Detalhado

Na aula de hoje, vou te ensinar como criar um calendário no Excel que atualiza e te informa as datas automaticamente. Basta inserir uma data e o calendário exibirá o mês correspondente, destacando a data escolhida.

Modelo do Calendário no Excel

Essa não será uma tarefa tão simples de se fazer, pois precisaremos utilizar um conjunto de fórmulas que irão criar essa ferramenta para nós. Veremos as funções DIA, MÊS, ANO, DATA, FIMMÊS, DIA.DA.SEMANA e SE. Sendo que a função SE será o foco principal e a mais importante na construção desse calendário.

Mas você não precisa se preocupar pois todo esse processo será explicado passo a passo detalhadamente. Então, não deixe de fazer o download do material da aula para poder acompanhar melhor cada etapa.

Explicando o funcionamento do calendário

Nosso calendário funciona da seguinte forma: você define uma data na célula K2 e, a partir dessa data, o Excel estrutura automaticamente o calendário do mês correspondente.

O calendário inclui todos os dias do mês e define corretamente o primeiro dia do mês, correspondendo ao dia da semana adequado, para termos um calendário preciso.

Além disso, nosso calendário no Excel funciona de forma dinâmica, atualizando automaticamente. Para isso, utilizaremos fórmulas e uma tabela auxiliar que criaremos. Essas fórmulas irão extrair todas as informações necessárias para criar o calendário com base na data informada na célula K2.

Exemplo do calendário no Excel funcionando

Criando a Tabela Auxiliar

Conforme mencionado anteriormente, para gerar nosso calendário, precisaremos obter algumas informações sobre a data em questão: dia, mês, ano, primeiro dia do mês, dia da semana em que o mês iniciou, último dia do mês e quantidade total de dias no mês.

São essas as informações que irão compor a nossa tabela auxiliar.

Informações da Tabela Auxiliar

Como nosso calendário deve funcionar de forma dinâmica e automática, cada célula em nossa tabela auxiliar será preenchida com fórmulas que, a partir da data informada na célula K2, obterão as informações necessárias.

Dessa forma, sempre que a data for atualizada, as demais informações também serão atualizadas automaticamente.

Para começar, precisamos separar o dia, mês e ano da data escolhida. Podemos fazer isso utilizando as funções DIA, MÊS e ANO, passando a célula K2 como argumento:

=DIA(K2)
=MÊS(K2)
=ANO(K2)
Funções DIA, MÊS e ANO
Valores das funções DIA, MÊS e ANO

A próxima informação necessária para o nosso calendário no Excel é o primeiro dia do mês correspondente à data informada. Podemos obter essa informação utilizando a função DATA, que retorna uma estrutura de data com base nos valores de ano, mês e dia fornecidos como argumento.

Para obter o primeiro dia do mês, passaremos a célula K6 para o ano, K5 para o mês e o número 1 para o dia, já que queremos o primeiro dia do mês.

=DATA(K6;K5;1)
Fórmula para o primeiro dia

Dessa forma, a fórmula nos retornará a data do primeiro dia do mês de fevereiro de 2023, conforme o que definimos na Data.

Tabela Auxiliar com as informações

Ainda em relação ao primeiro dia do mês, precisamos informar ao nosso calendário no Excel em qual dia da semana esse mês se inicia.

Para fazer isso, utilizamos a função DIA.DA.SEMANA, que recebe uma data e retorna o número correspondente ao dia da semana, variando de 1 a 7, onde 1 representa domingo e 7 representa sábado.

 Como argumento, passamos a célula K7, onde está armazenada a data do primeiro dia do mês.

=DIA.DA.SEMANA(K7)
Função DIA.DA.SEMANA
Tabela auxiliar com Dida da Semana

A fórmula retornou o número 4, que corresponde à quarta-feira.

Agora, precisamos descobrir o último dia do mês e, a partir dele, determinar quantos dias o mês possui.

Para obter a data do último dia do mês, utilizaremos a função FIMMÊS, passando a célula K2 como argumento para representar a nossa data e o número 0 como segundo argumento.

=FIMMÊS(K2;0)
Função FIMMÊS

Esse segundo argumento serve para informar à fórmula a quantidade de meses que desejamos avançar ou retroceder a partir da data informada. Por exemplo, se quiséssemos obter a data do último dia do mês de março, deveríamos substituir o número 0 pelo número 1.

Tabela auxiliar com a data do último dia

Para obter a quantidade de dias presentes no mês da data selecionada, podemos usar novamente a função DIA. No entanto, desta vez, utilizaremos a célula K9 como argumento, que contém a data do último dia do mês. Isso nos fornecerá o número de dias presentes no mês da nossa data selecionada.

=DIA(K9)
Todas as funções da tabela auxiliar
Tabela Auxiliar preenchida

Assim, concluímos a nossa tabela auxiliar.

Construindo o Calendário no Excel

Com a nossa tabela pronta podemos partir para a criação do nosso calendário no Excel.

Como a nossa tabela auxiliar já trata os dias da semana como números, vamos criar uma linha auxiliar diretamente acima do calendário para atribuir a cada dia da semana o seu número correspondente, utilizando os valores de 1 a 7.

Linha auxiliar

Agora, utilizaremos a fórmula SE para verificar cada célula da primeira semana do calendário. Se o valor contido na linha auxiliar, na mesma coluna, for igual ao valor presente na célula K8 (Dia da Semana), então a célula deve ser preenchida com o número 1, pois é o primeiro dia do mês.

Podemos definir essa fórmula na célula B3 e depois copiá-la para as demais células da primeira semana do calendário, seja arrastando ou usando os comandos Ctrl + C e Ctrl + V.

=SE(B1=$K$8;1;"")

O primeiro valor dessa função é um teste lógico que compara a célula na linha auxiliar com a célula na tabela auxiliar. Se o resultado for verdadeiro, a célula correspondente será preenchida com o número 1. Caso contrário, ela ficará vazia.

Estamos utilizando o argumento $K$8 para “trancar” o valor da célula K8. Isso garante que, ao copiarmos a fórmula para as outras células na mesma linha, o argumento da célula K8 não se desloque para K9, K10, e assim por diante.

Até aqui já é possível preencher o primeiro dia no nosso calendário.

Primeiro dia preenchido

Mas repare que passamos para a fórmula SE que caso o teste de lógica retorne como “falso“, ela deve deixar as linhas vazias, e não queremos isso. Queremos preencher o calendário por completo. Então, vamos aprimorar nossa fórmula adicionando mais uma função SE:

=SE(B1=$K$8;1;SE(A3="";"";A3+1))

Explicando a fórmula em detalhes:

  • Primeiro, fazemos uma comparação entre a linha auxiliar, onde colocamos os dias de 1 a 7, e o Dia da Semana (K8), que corresponde à data que estamos buscando.
  • Se o dia da semana for igual ao dia da linha auxiliar, colocamos o número 1, indicando o início do mês.
  • Caso essa verificação seja falsa, verificamos se o dia anterior ao analisado está vazio. Se estiver, atribuímos o valor vazio ao dia atual, indicando que o mês ainda não começou.
  • Por fim, se o dia anterior ao analisado não estiver vazio, somamos 1 a este valor. Isso acontece porque o mês já se iniciou e precisamos continuar a contagem.

Agora que temos a fórmula pronta na célula B3, podemos copiá-la para as demais células da primeira linha do nosso calendário, assim teremos a primeira semana completa.

Primeira semana completa

Vamos preencher as três semanas do meio do nosso calendário. Como a primeira semana já está preenchida, não precisamos de uma fórmula diferenciada, apenas pegaremos o dia anterior e somaremos 1. Porém, precisamos ter atenção, pois teremos duas fórmulas diferentes.

Para o domingo, precisamos referenciar a coluna do sábado e somar 1. Já para os demais dias da semana, só precisamos fazer referência à célula da coluna anterior e somar 1.

Fórmula para as semanas do meio

Feito isso, podemos replicar essas fórmulas para as linhas de baixo, preenchendo assim as três semanas do meio do nosso calendário.

Copiando a fórmula para as demais semanas
Semanas do meio preenchidas

Para as duas últimas semanas, teremos que utilizar uma fórmula diferente para verificar a data final daquele mês e evitar que o calendário continue sendo preenchido após o término do mês.

Calendário preenchendo datas inexistentes
Calendário preenchendo datas não existentes.

Para evitar que isso aconteça, precisamos verificar se a data anterior à célula atual corresponde ao valor do último dia do mês.

Se a data anterior for o último dia, deixaremos a célula vazia. Caso contrário, verificaremos se o valor está preenchido (indicando que o mês ainda não acabou) e somaremos 1, ou se o valor estiver vazio (indicando que o mês já acabou), também deixaremos a célula vazia.

Assim como fizemos para preencher os dias, precisaremos de uma fórmula para os domingos e outra para os dias da semana.

Fórmula para os domingos:

=SE(H6="";"";SE(H6+1>$K$10;"";H6+1)

Fórmula para os demais dias (segunda a sábado):

=SE(B7="";"";SE(B7+1>$K$10;"";B7+1)

Explicando as fórmulas:

  • Primeiro, fazemos uma comparação da célula anterior para verificar se ela está vazia. Em caso positivo, deixamos a célula atual vazia.
  • Caso contrário, verificamos se a célula anterior + 1 é maior do que o último dia do mês. Se for, atribuímos o valor vazio, indicando que o mês já acabou. Se não for, apenas continuamos somando mais 1.
  • Ambas as fórmulas funcionam da mesma maneira, com a diferença que a fórmula dos domingos precisa pegar as informações da coluna de sábado, enquanto os outros dias da semana podem pegar da coluna anterior.

Com as fórmulas prontas, podemos aplicar a fórmula da segunda-feira para todo o restante da linha e replicá-la para a semana abaixo também, completando assim as duas últimas semanas do nosso calendário.

Calendário com as datas corretas

Alterando a Data podemos verificar que nosso calendário no Excel atualiza automaticamente.

Calendário atualizado após trocar a data

Colocando a Data em Realce

Com nosso calendário no Excel funcionando perfeitamente e atualizando conforme modificamos a data, só precisamos implementar a opção de realçar o dia da data selecionada. Para isso, utilizaremos a ferramenta de Formatação Condicional.

Para começar, selecionamos o calendário inteiro, da célula B3 até a célula H8.

Selecionando todas as células do calendário

Vamos clicar em Formatação Condicional

Selecionando formatação condicional

Selecionamos Realçar Regras das Células e em seguida É igual a. Desta forma, podemos escolher como a célula será realçada ao ser encontrada no intervalo selecionado.

Configurando a formatação condicional

Nessa opção, podemos especificar que queremos que o Excel realce a célula correspondente ao valor de K4, que representa o nosso dia.

Selecionando estilo de realce

Assim, nosso calendário no Excel ficará completo e com o dia escolhido realçado.

Calendário completo e funcionando o realce

Conclusão – Calendário no Excel

Nessa aula, você aprendeu como criar um calendário no Excel automático e dinâmico com base em uma data selecionada.

Seguindo cada etapa e compreendendo as fórmulas utilizadas, você foi capaz de obter informações sobre um determinado mês e destacar o dia selecionado dentro do calendário para facilitar a visualização.

Embora tenha exigido um pouco de trabalho, esse exercício foi excelente para você estudar e colocar em prática seus conhecimentos em Excel. Portanto, não deixe de criar seu próprio calendário no Excel para aprimorar ainda mais suas habilidades!

Hashtag Free Excel Básico

Apostila Básica de Excel

Essa é uma apostila básica de Excel para que você saia do zero de forma 100% gratuita!

Hashtag Treinamentos

Para acessar outras publicações de Excel Avançado, clique aqui!


Quer aprender mais sobre Excel com um minicurso básico gratuito?

Quer ter acesso a um Minicurso de Finanças no Excel de forma 100% gratuita? Preencha seu e-mail abaixo!